Line break to remove if column is blank

[Moniker]

My current expression is
CONCATENATE(
if(isnotblank([WASHING]),Concatenate(Washing," - ",[WASHING]),"")&"
"&
if(isnotblank([DAMAGE]),Concatenate(Damage," - ",[DAMAGE]),"")&"
"&
if(isnotblank([Road Fare]),Concatenate(Road," - ",[Road Fare]),"")&"
"&
if(isnotblank([Others]),Concatenate(Others," - ",[Others]),"")
)

[Steve]

Try this:

CONCATENATE(
  IFS((0 <> [WASHING]), ("Washing - " & [WASHING])), "
  ", IFS((0 <> [DAMAGE]), ("Damage - " & [DAMAGE])), "
  ", IFS((0 <> [Road Fare]), ("Road - " & [Road Fare])), "
  ", IFS((0 <> [Others]), ("Others - " & [Others]))
)

[Moniker]

Line break was still there.

[Steve]

Whoops! I misunderstood. Try this instead:

CONCATENATE(
IFS((0 <> [WASHING]), ("Washing - " & [WASHING] & "
")), IFS((0 <> [DAMAGE]), ("Damage - " & [DAMAGE] & "
")), IFS((0 <> [Road Fare]), ("Road - " & [Road Fare] & "
")), IFS((0 <> [Others]), ("Others - " & [Others]))
)

[Steve · Accepted solution]

Or this:

SUBSTITUTE(
  CONCATENATE(
    LIST(
      IFS((0 <> [WASHING]), ("Washing - " & [WASHING])),
      IFS((0 <> [DAMAGE]), ("Damage - " & [DAMAGE])),
      IFS((0 <> [Road Fare]), ("Road - " & [Road Fare])),
      IFS((0 <> [Others]), ("Others - " & [Others]))
    )
    - LIST("")
  ),
  " , ",
  "
"
)

[Moniker]

It really worked.
Thank my Steve Bro.
I will try to understand this.
Again, Thanks.
It was not a big thing for many but It had been gnawing at me for weeks now.