Custom message in invalid value error

[eldderri]

Hi friends,

     In my app ,I have a form named Checklist with a column named:"Matricule Camion" with type enum. I have this formula in the valid if column:

ISBLANK(
FILTER(
"CheckList",
AND(
[Matricule Camion] = [_THISROW].[Matricule Camion],
IN([Action], {"Bloqué", "Maintenance programmée"})
)
))

I want to display two different messages in invalid value error:

1. When [Action]="Bloqué"  ,message would be:"The truck is blocked"
2. When [Action]="Maintenance programmée" ,message would be :"Truck is planned for maintenance"

How to achieve this functionality?

Best regards,

[jballester]

Hi, 

check..

Virtual Colum; [message]
App; 

""

Show?

ISNOTBLANK([Action])

Type; Show
Category; Text
Content; 

IFS(
[Action]="Bloqué","The truck is blocked",
[Action]="Maintenance programmée" ,"Truck is planned for maintenance"
 )

Edit. Thanks. @Steve 

[eldderri]

Hi,

Where shall I put this part:

Type; Show
Category; Text
Content; 

IFS(
[_THISROW].[Action]="Bloqué","The truck is blocked",
[_THISROW].[Action]="Maintenance programmée" ,"Truck is planned for maintenance"
 )

[jballester]

Type / Type details

 

[eldderri]

I mean which column?

[jballester]

Virtual Colum; [message]

[eldderri]

I have done all the steps but the virtual column message is not displayed,because I think when a virtual column is primarily has no value it does not show.And in this case this column shall never be populted until Action is filled which is not what I am aiming to.What I want is to display a message as soon as the Matricule Camion value is found in my chechkist database and has either Bloqué or Maintenance programmé in Action column to avoid making duplicate checklist to the same truck.

Best regards,

[Steve · Accepted solution]

Here is my alternative:

1. Add a column named (e.g.) Statut matricule camion of type Text with Show? off and the following App formula expression:

SWITCH(
  ANY(
    INTERSECT(
      {"Bloqué", "Maintenance programmée"},
      SELECT(
        CheckList[Action],
        AND(
          ([_THISROW].[Matricule Camion] = [Matricule Camion]),
          IN([Action], {"Bloqué", "Maintenance programmée"})
        )
      )
    )
  ),
  "Bloqué",
    "The truck is blocked",
  "Maintenance programmée",
    "Truck is planned for maintenance",
  ""
)

 2. For the existing Matricule Camion column, replace the existing Valid if expression with this:

ISBLANK([Statut matricule camion])

And set the Invalid value error expression to this:

[Statut matricule camion]

The App formula of the Statut matricule camion column determines whether the truck has a concern and describes the concern if any. The Valid if of the Matricule Camion uses the absence of a concern in Statut matricule camion to mean Matricule Camion is valid. If it isn't valid, the concern noted in Statut matricule camion is displayed as the error message.

[Steve]

[_THISROW]. is entirely unneeded here. Using it where not needed can introduce problems.

[eldderri]

Thank you so much .It worked as expected