Can I have more then 1 key ( Column ) ? I tried but I couldn’t make it.
The reason is this:
I made 1 key for column [ MOBILE] and it cant be entered repeatedly, I want in column [EMAIL] to be the same ( Not entered repeatedly ).
Solved! Go to Solution.
You can have only one key column. Note that the key column value can never change once a row is saved, which could be a problem if a user wants to change their phone number. Better to choose a key value that can be guaranteed to never change. One common option is to generate a key value using the UNIQUEID() function.
To prevent other columns from having duplicate values, you need to use a Valid If expression similar to this:
ISBLANK(
FILTER(
"REGISTER",
AND(
ISNOTBLANK([EMAIL]),
([EMAIL] = [_THISROW].[EMAIL])
)
)
- LIST([_THISROW])
)
FILTER("REGISTER", ...)
gathers the rows in the REGISTER table that meet the given criteria (...
; see (2)). See also: FILTER().
AND(..., ...)
matches only rows that meet both criteria (see (3) & (4)). See also: AND().
ISNOTBLANK([EMAIL])
matches only rows where the EMAIL column value is not blank. See also: ISNOTBLANK().
([EMAIL] = [_THISROW].[EMAIL])
matches only rows where the EMAIL column value ([EMAIL]
) matches the same column value in the current form ([_THISROW].[EMAIL]
).
... - LIST([_THISROW])
removes the row in the form ([_THISROW]
) from the list of gathered rows (...
; see (1)). See also: LIST().
ISBLANK(...)
asks whether the constructed list (...
; see (5)) is empty. If so, the table contains no other rows with the same EMAIL column value. See also: ISBLANK().
User | Count |
---|---|
40 | |
36 | |
33 | |
23 | |
17 |