Solved: Starting View - Page 2

Alejandra_Petro · 08-24-2019 09:55 PM

Hello,

I have two views “My Jobs” and “Loads”. How can I do for the app to start with “My Jobs” if the user is a driver and “Loads” if the user is a supervisor.

Thanks in advance for your help!

MultiTech

I assume you’ve got a Users table, and in that table you’ve got two things:

a column holding the email that the user will use to log in; and
a column holding the role of the user.

If these conditions are true, then there’s two good ways to handle this:

LOOKUP(USEREMAIL(), Users, User_Email, User_Role); or
Create a slice on the users table, with a condition that matches the USEREMAIL() = [User_Email], call it Current_User - from here you can always easily call any information from the current user’s record: any(Current_User[Any_Column])

Either way you can now call data from the specific user’s record and make determinations with it.

Switch(any(current_user[User_Role]),
  "Driver", "My Jobs", 
  "Supervisor", "Loads", 
  "Some fallback/default view"
)

or

If(
  any(current_user[User_Role]) = "Driver", "My Jobs", 
If(
  any(current_user[User_Role]) = "Supervisor", "Loads", 
"Some fallback/default view"
))

or

IFS(
  any(current_user[User_Role]) = "Driver", "My Jobs", 
      any(current_user[User_Role]) = "Supervisor", "Loads"
)

To use the LOOKUP() instead of the Current_User (Slice) just replace the any(current_user[User_Role]) portion of any of the formulas above

IFS(
   LOOKUP(USEREMAIL(), Users, User_Email, User_Role) = "Driver", "My Jobs", 
       LOOKUP(USEREMAIL(), Users, User_Email, User_Role) = "Supervisor", "Loads"
)

View solution in original post